Find/Replace plain text with a text form field

Hi,

I have a system that can create Word documents where all the document
content comes out of a database.

I want to find/replace specific text in these Word documents with a form
field, for example, I have some text called "first_name" but want to replace
it with a text form field. Or I have some text "yes/no" that I want to
replace with a check box form field.

Can this be done?
If so, can it be done with a macro, or does it need something more heavy
duty?

Thanks,
Colin

"CR Geissler" wrote:

> Hi,
>
> I have a system that can create Word documents where all the document
> content comes out of a database.
>
> I want to find/replace specific text in these Word documents with a form
> field, for example, I have some text called "first_name" but want to replace
> it with a text form field. Or I have some text "yes/no" that I want to
> replace with a check box form field.
>
> Can this be done?
> If so, can it be done with a macro, or does it need something more heavy
> duty?

Yes, it can be done, and no, it is not heavy duty!
Here is my take on it:


Option Explicit

Const textFF As String = "First_Name"
Const checkFF As String = "Yes/No"

Sub FindText()

Dim rngFind As Range
Dim i As Long

i = 1
Set rngFind = ActiveDocument.Range
With rngFind.Find
.Text = textFF
Do While .Execute
AddFormField textFF, rngFind, textFF & i, "Enter your name"
i = i + 1
rngFind.Start = rngFind.End
rngFind.End = ActiveDocument.Range.End
Loop
End With

i = 1
Set rngFind = ActiveDocument.Range
With rngFind.Find
.Text = checkFF
Do While .Execute
AddFormField checkFF, rngFind, "Yes_No" & i
i = i + 1
rngFind.Start = rngFind.End
rngFind.End = ActiveDocument.Range.End
Loop
End With

End Sub

Sub AddFormField(strType As String, rngFF As Range, _
strName As String, Optional strDefault As String)

Dim frmfldReplace As FormField

Select Case strType
Case checkFF
Set frmfldReplace = rngFF.FormFields.Add(rngFF, wdFieldFormCheckBox)
With frmfldReplace
.Name = strName
End With
Case textFF
Set frmfldReplace = rngFF.FormFields.Add(rngFF, wdFieldFormTextInput)
With frmfldReplace
.Name = strName
.TextInput.Default = strDefault
.Result = .TextInput.Default
End With
End Select

End Sub