Default template

Hi all

I've made 3 macros on my computer and now I need to install these on a
couple of other computers.

I want to make a new toolbar, with 3 buttons that call these macro's.

Where can I find the default excel template? And how do I copy te macro's to
this one. If I save the new toolbar in this file and I copy this to other
PC's, do they got the toolbar automaticly aswell, or do I need to make the
toolbar on every PC?

Kind regards
Erwin

I think the best way would be to simply export the macros and have
your users import them to their personal workbook.

1. To find/create a default workbook/sheet for Excel, check out

http://www.bettersolutions.com/excel/EHN113/VT621416331.htm

2. To be efficient, you can create the toolbar at runtime, for example

Private Sub Workbook_Open()
Dim cmdbar As CommandBar
Dim cmdbtn1 As CommandBarButton
Dim cmdbtn2 As CommandBarButton
Dim cmdbtn3 As CommandBarButton

Set cmdbar = Application.CommandBars.Add(Name:="My Toolbar")
Set cmdbtn1 = cmdbar.Controls.Add(msoControlButton)
Set cmdbtn2 = cmdbar.Controls.Add(msoControlButton)
Set cmdbtn3 = cmdbar.Controls.Add(msoControlButton)

With cmdbtn1
.Style = msoButtonIconAndCaption
.Caption = "Something to Do"
.OnAction = "Module1.SomeMacroInModule1"
'.Width = 170
'.FaceId = 643
End With

With cmdbtn2
.Style = msoButtonIconAndCaption
.Caption = "Something Else to Do"
.OnAction = "Module1.SomeOtherMacroInModule1"
'.Width = 170
'.FaceId = 643
End With

With cmdbtn3
.Style = msoButtonIconAndCaption
.Caption = "Last thing to Do"
.OnAction = "Module1.LastMacroInModule1"
'.Width = 170
'.FaceId = 643
End With

With cmdbar
.Visible = True
End With

End Sub

Private Sub Workbook_BeforeClose(Cancel As Boolean)
On Error Resume Next
Application.CommandBars("My Toolbar").Delete
End Sub

These macros should be placed in the 'ThisWorkbook' module for the
workbook you are creating.


HTH,
JP


On Jan 9, 6:25 am, "Erwin Bormans"
<erwin.bormans.RemoveThis@verwijderdit_telenet.be> wrote:
> Hi all
>
> I've made 3 macros on my computer and now I need to install these on a
> couple of other computers.
>
> I want to make a new toolbar, with 3 buttons that call these macro's.
>
> Where can I find the default excel template? And how do I copy te macro's to
> this one. If I save the new toolbar in this file and I copy this to other
> PC's, do they got the toolbar automaticly aswell, or do I need to make the
> toolbar on every PC?
>
> Kind regards
> Erwin